@title CAMremote-SDM
rem by VP-Systems
rem 25-04-2010

m=0

rem CAMremote-2 (Mini USB connector).  Control Method: USB/CHDK+
print "CR: USB/CHDK+"
while 1
   do
     a = get_usb_power
   until a>0
   if a<2 then gosub "shoot" else if a<4 then gosub "focus" else if a<6 then gosub "focusoff" else if a<8 then gosub "zin" else if a<10 then gosub "zout" else if a<12 then gosub "rec_video" else if a<14 then gosub "avup" else if a<16 then gosub "avdn" else if a<18 then gosub "tvup" else if a<20 then gosub "tvdn" else if a<22 then gosub "stop_video" else if a<42 then gosub "lensoff" else if a<52 then gosub "pwroff"

   a=0
wend
end

:shoot
  print "shoot:";a
  press "shoot_full"
  sleep 1500
  release "shoot_full"
  release "shoot_half"
  return

:rec_video
  if m=1 then return
  movie_mode
  sleep 2000
  print "rec_video:";a
  press "shoot_full"
  sleep 1500
  release "shoot_full"
  release "shoot_half"
  m=1
  return

:stop_video
  if m=0 then return
  print "stop_video:";a
  press "shoot_full"
  sleep 1500
  release "shoot_full"
  release "shoot_half"
  m=0
  record_mode
  sleep 2000
  return

:video
  if m=0 then gosub "rec_video" else gosub "stop_video"
  return

:focus
  print "focus:";a
  press "shoot_half"
  return

:focusoff
  print "release:";a
  release "shoot_half"
  return

:zin
  print "zoomin:";a
  click "zoom_in"
  release "shoot_half"
  return

:zout
  print "zoomout:";a
  click "zoom_out"
  release "shoot_half"
  return

:avup
  print "Av+:";a
  set_av_rel 0+1
  return

:avdn
  print "Av-:";a
  set_av_rel 0-1
  return

:tvup
  print "Tv+:";a
  set_tv_rel 0+1
  return

:tvdn
  print "Tv-:";a
  set_tv_rel 0-1
  return

:capture
  print "capture:";a
  press "shoot_full"
  sleep 500
  release "shoot_full"
  release "shoot_half"
  sleep 1500
  return

:lensoff
  print "lensoff not supported"
  shut_down
  sleep 1000
  return

:pwroff
  print "poweroff"
  shut_down
  sleep 1000

return